Skip to main content

Hvordan benytte foreldreopplysninger i analyser

I databasen finnes det variabler for fars og mors fødselsnumre, noe som gjør at en kan koble opplysninger om foreldre på et persondatasett.

Gjennom kommandoen merge kan en koble sammen datasett. Hovedidentifikatorvariabel i måldatasettet brukes som standard. Dette kan imidlertid overstyres gjennom en on-opsjon.

I eksempelet lages det et eget datasett for foreldre, som kobles sammen med et persondatasett via koblingsnøklene fnr_far og fnr_mor.

 //Kobler til databank
require no.ssb.fdb:23 as db

//Lager et persondatasett med lenker til far og mor
create-dataset persondata
import db/INNTEKT_WYRKINNT 2021-01-01 as inntekt
import db/BEFOLKNING_KJOENN as kjønn
import db/NUDB_BU 2021-01-01 as utd
import db/BEFOLKNING_FAR_FNR as fnr_far
import db/BEFOLKNING_MOR_FNR as fnr_mor

//Henter opplysninger om foreldre og kobler på persondatasett
create-dataset foreldredata
import db/INNTEKT_WYRKINNT 2021-01-01 as inntekt_far
import db/NUDB_BU 2021-01-01 as utd_far
clone-variables inntekt_far -> inntekt_mor
clone-variables utd_far -> utd_mor
merge inntekt_far utd_far into persondata on fnr_far
merge inntekt_mor utd_mor into persondata on fnr_mor

//Kjører en enkel lineær regresjon for å teste sammenheng mellom egen og foreldres inntekt
use persondata
generate mann = 0
replace mann = 1 if kjønn == '1'

destring utd
generate høyutd = 0
replace høyutd = 1 if utd >= 700000 & utd < 900000
replace høyutd = utd if sysmiss(utd)

destring utd_far
generate høyutd_far = 0
replace høyutd_far = 1 if utd_far >= 700000 & utd_far < 900000
replace høyutd_far = utd_far if sysmiss(utd_far)

destring utd_mor
generate høyutd_mor = 0
replace høyutd_mor = 1 if utd_mor >= 700000 & utd_mor < 900000
replace høyutd_mor = utd_mor if sysmiss(utd_mor)

summarize inntekt inntekt_far inntekt_mor
histogram inntekt_far, percent
histogram inntekt_mor, percent
correlate inntekt_far inntekt_mor
tabulate høyutd_far høyutd_mor

regress inntekt mann inntekt_far inntekt_mor høyutd høyutd_far høyutd_mor