Hvordan lage populasjoner

I microdata.no brukes left-join-prinsippet. Det betyr at første variabelen som opprettes bestemmer populasjonens størrelse. Om dette er en universell variabel som f.eks. kjønn, vil datasettet ditt bestå av flest mulig individer fra den totale databasen, inkludert personer som er døde, emigrerte eller ikke er født på det tidspunktet en ønsker å analysere.

Begynner du med å importere en variabel som bare gjelder et begrenset antall individer som f.eks. uføretrygd, vil datasettet ditt kun bestå av personer i Norge som mottok uføretrygd på det aktuelle tidspunktet du måler for.

En kan ikke gjøre populasjonen større enn det variabel nr. 1 gir mulighet for. Så en må tenke over hvilken variabel en begynner å importere, slik at en får med seg alle personene en ønsker å analysere. En kan imidlertid gjøre populasjoner mindre om en ønsker. Dette gjøres ved å bruke kommandoen drop if eller keep if.

//Eksempel 1: Populasjon = alle bosatte i Bergen per 1/6 2015
create-dataset eks1
import BOSATTEFDT_BOSTED 2015-06-01 as bosted
keep if bosted == '1201'

//Eksempel 2: Populasjon = alle bosatte i Hordaland per 1/6 2015
create-dataset eks2
import BOSATTEFDT_BOSTED 2015-06-01 as bosted
keep if substr( bosted,1,2) == '12'

//Eksempel 3: Populasjon = alle med en yrkesinntekt i året 2015  
//(= alle med en årlig yrkesinntekt > 0 i 2015)
create-dataset eks3
import INNTEKT_WYRKINNT 2015-06-01 as yrkesinntekt

//Eksempel 4: Når en begynner med en universell variabel men egentlig vil 
//analysere individer med gitte egenskaper på et gitt tidspunkt
create-dataset eks4
import BEFOLKNING_KJOENN as kjønn
import INNTEKT_WYRKINNT 2015-06-01 as yrkesinntekt
drop if sysmiss( yrkesinntekt )

//Eksempel 5: Når en begynner med en universell variabel men egentlig vil 
//analysere individer som faktisk var bosatt i Norge på et gitt tidspunkt.
//Variabelen BEFOLKNING_REGSTAT er egnet til dette formålet da den inneholder
//koder for hhv. "bosatt","død" og "emigrert". "Bosatt" har koden '1'.
create-dataset eks5
import BEFOLKNING_KJOENN as kjønn
import BEFOLKNING_REGSTAT 2015-06-01 as registerstatus
keep if registerstatus == '1'